Nachhaltig Excel-Blatt mit VBA ansprechen.

Um ein Excel-Blatt per VBA anzusprechen wird oft der Index oder den Namen des Blattes verwendet. Dies kann jedoch in der Praxis zu Fehlern führen, sobald das Blatt sich an einer anderen Stelle befindet oder umbenannt wurde. Besser ist den CodeName zu verwenden.

Variante 1: Verwendung des Indexes

Sub Var1()
  Dim ws As Worksheet
  Set ws = Worksheets(1)
  ws.Name = "Januar"
End Sub
Der Nachteil dieser Variante ist, sobald das Blatt vom Anwender verschoben
wird, verwendet der VBA-Code das falsche Blatt.

Variante 2: Verwendung des Blattnamens

Sub Var2()
  Dim ws As Worksheet
  Set ws = Worksheets("Tabelle1")
  ws.Name = "Januar"
End Sub
Der Nachteil dieser Variante ist, sobald das Blatt vom Anwender umbenannt
wird, erzeugt der VBA-Code einen Fehler. Spätestens beim 2. Aufruf erhalten wir
zwangsläufig einen Fehler.

Variante 3: Verwendung des Objektnamens (CodeName)

Sub Var3()
  Dim ws As Worksheet
  Set ws = Tabelle1
  ws.Name = "Januar"
End Sub
Diese Variante ist optimal. Der Code kann beliebig oft ausgeführt werden
ohne einen Fehler zu erzeugen.

Sollte jedoch das Blatt sich nicht in der aktiven Arbeitsmappe befinden, kann dieses nicht mit dem CodeName angesprochen werden!

Mit der folgenden Funktion wird dies doch möglich:
Public Function GetSheetFromCodeName(CodeName As String, _
  Optional Sheet As Object, _
  Optional InWorkbook As Workbook) As Boolean 

  If InWorkbook Is Nothing Then Set InWorkbook = ThisWorkbook
  For Each Sheet In InWorkbook.Sheets
    If StrComp(Sheet.CodeName, CodeName, vbTextCompare) = 0 Then
     GetSheetFromCodeName = True
      Exit For
    End If
  Next 

End Function
 

Beispielaufruf:

Sub Var4()
  Dim ws As Worksheet
  If GetSheetFromCodeName("Tabelle1", ws, Workbooks("Datei.xls")) Then
    ws.Name = "Januar"
  Else
    MsgBox "An den Programmierer: Der Codename ist nicht vorhanden!", vbCritical
  End If
End Sub
Anmerkung:

Gleichzeitig wird mit der Funktion GetSheetFromCodeName geprüft, ob das Objekt gar vorhanden ist. Diese Funktion kann auch nur für diese Prüfung benutzt werden.
Ich würde empfehle immer diese Funktion zu verwenden. Falls der Programmierer sicherstellt, dass das Objekt immer vorhanden ist, kann auch die IF-Abfrage weggelassen werden.

Beispielaufruf:

Sub Var5()
  Dim ws As Worksheet
  GetSheetFromCodeName "Tabelle1", ws
  ws.Name = "Januar"
End Sub